MacFormat 1997 February/macformat-047.iso/Demos/Simpsons Cartoon Studio™ Demo/Simpdata/simpmain/00002_interfaceManager parent.ls

Text File | 1996-09-06 | 9.1 KB | 232 lines

property panelCastNum, panelCastNumLst, btnBoundsLst, btnActionLst, btnSoundLst, btnPosLst, btnCastNumLst, btnSelCastNumLst, topPanelCastNumLst, bottomPanelCastNumLst, rightPanelCastNumLst, leftPanelCastNumLst
global gPlayFlag, gLoopFlag, topPanelSpr, bottomPanelSpr, leftPanelSpr, rightPanelSpr, shuttleSpr, shuttleFldSpr, playBtnSpr, loopBtnSpr, fileNameFieldSpr, loopStatusFieldSpr, soundStatusFieldSpr, buttonHiliteSpr, currentFrame

on birth me
  set topPanelSpr to 24
  set bottomPanelSpr to topPanelSpr + 1
  set leftPanelSpr to topPanelSpr + 2
  set rightPanelSpr to topPanelSpr + 3
  set buttonHiliteSpr to topPanelSpr + 4
  set shuttleSpr to topPanelSpr + 5
  set shuttleFldSpr to topPanelSpr + 6
  set playBtnSpr to topPanelSpr + 7
  set loopBtnSpr to topPanelSpr + 8
  set fileNameFieldSpr to topPanelSpr + 9
  set loopStatusFieldSpr to topPanelSpr + 10
  set soundStatusFieldSpr to topPanelSpr + 11
  puppetSprites(topPanelSpr, soundStatusFieldSpr, 1)
  set gLoopFlag to 0
  set gPlayFlag to 0
  set panelCastNumLst to [#topPanelSpr: the number of cast "top panel base", #bottomPanelSpr: the number of cast "bottom panel base", #rightPanelSpr: the number of cast "right panel base", #leftPanelSpr: the number of cast "left panel base"]
  set topPanelCastNumLst to [the number of cast "new hilite", the number of cast "open hilite", the number of cast "save hilite", the number of cast "save as hilite", the number of cast "quit hilite"]
  set rightPanelCastNumLst to [the number of cast "homer hilite", the number of cast "marge hilite", the number of cast "bart hilite", the number of cast "lisa hilite", the number of cast "maggie hilite", the number of cast "cameo hilite", the number of cast "props hilite", the number of cast "soundFX hilite", the number of cast "specialFX hilite", the number of cast "backgrounds hilite"]
  set bottomPanelCastNumLst to [the number of cast "rewind hilite", the number of cast "fastforward hilite", the number of cast "stepback hilite", the number of cast "stepforward hilite", the number of cast "cut hilite"]
  set leftPanelCastNumLst to [the number of cast "memory hilite", the number of cast "volume hilite", the number of cast "export hilite"]
  set btnSelCastNumLst to [the number of cast "homer selected", the number of cast "marge selected", the number of cast "bart selected", the number of cast "lisa selected", the number of cast "maggie selected", the number of cast "cameo selected", the number of cast "props selected", the number of cast "soundFX selected", the number of cast "specialFX selected", the number of cast "backgrounds selected"]
  return me
end

on panelClick me, theMouseH, theMouseV, whichSpr
  set panelSeqLst to ["top", "bottom", "left", "right"]
  set panelPrefix to getAt(panelSeqLst, whichSpr - topPanelSpr + 1)
  set panelCastNum to getaProp(panelCastNumLst, value("#" & panelPrefix & "PanelSpr"))
  set btnCastNumLst to value(panelPrefix & "PanelCastNumLst")
  set btnBoundsLst to value(line 1 of field (panelPrefix & "PanelData"))
  set btnPosLst to value(line 2 of field (panelPrefix & "PanelData"))
  set btnActionLst to value(line 3 of field (panelPrefix & "PanelData"))
  set btnSoundLst to value(line 4 of field (panelPrefix & "PanelData"))
  if panelPrefix = "right" then
    set clickType to #TOGGLE
  else
    set clickType to #NORMAL
  end if
  buttonClick(me, theMouseH, theMouseV, whichSpr, clickType)
end

on buttonClick me, theMouseH, theMouseV, whichSpr, clickType
  set theMouseH to theMouseH - the left of sprite whichSpr
  set theMouseV to theMouseV - the top of sprite whichSpr
  set theMouseLoc to point(theMouseH, theMouseV)
  if soundBusy(2) then
    puppetSound(2, 0)
  end if
  repeat with buttonNum = 1 to count(btnBoundsLst)
    set theButtonBounds to getAt(btnBoundsLst, buttonNum)
    if inside(theMouseLoc, theButtonBounds) then
      set soundCastNum to the number of cast getAt(btnSoundLst, buttonNum)
      puppetSound(2, soundCastNum)
      set hiliteCastNum to getAt(btnCastNumLst, buttonNum)
      set hiliteButtonLoc to getAt(btnPosLst, buttonNum)
      set the castNum of sprite buttonHiliteSpr to hiliteCastNum
      set the loc of sprite buttonHiliteSpr to hiliteButtonLoc
      set the width of sprite buttonHiliteSpr to the width of cast hiliteCastNum
      set the height of sprite buttonHiliteSpr to the height of cast hiliteCastNum
      updateStage()
      set hilite to 1
      startTimer()
      repeat while the timer < 6
      end repeat
      if the mouseDown then
        repeat while the mouseDown
          set theMouseH to the mouseH - the left of sprite whichSpr
          set theMouseV to the mouseV - the top of sprite whichSpr
          set theMouseLoc to point(theMouseH, theMouseV)
          if inside(theMouseLoc, theButtonBounds) then
            set the loc of sprite buttonHiliteSpr to hiliteButtonLoc
            set hilite to 1
          else
            set the locH of sprite buttonHiliteSpr to -1000
            set hilite to 0
          end if
          updateStage()
        end repeat
      end if
      if hilite then
        if clickType = #TOGGLE then
          unLoadCast(soundCastNum)
          set hiliteCastNum to getAt(btnSelCastNumLst, buttonNum)
          set hiliteButtonLoc to getAt(btnPosLst, buttonNum)
          set the castNum of sprite buttonHiliteSpr to hiliteCastNum
          set the loc of sprite buttonHiliteSpr to hiliteButtonLoc
          set the width of sprite buttonHiliteSpr to the width of cast hiliteCastNum
          set the height of sprite buttonHiliteSpr to the height of cast hiliteCastNum
          updateStage()
        else
          unLoadCast(soundCastNum)
          unLoadCast(hiliteCastNum)
          set the locH of sprite buttonHiliteSpr to -1000
          updateStage()
        end if
        cursor(4)
        do(getAt(btnActionLst, buttonNum))
        cursor(-1)
      else
        unLoadCast(soundCastNum)
        unLoadCast(hiliteCastNum)
        set the locH of sprite buttonHiliteSpr to -1000
        updateStage()
      end if
      exit repeat
    end if
  end repeat
end

on loopBtnClick me
  set hilit to 1
  if gLoopFlag then
    set direction to -1
  else
    set direction to 1
  end if
  set theCastNum to the castNum of sprite loopBtnSpr
  set the castNum of sprite loopBtnSpr to theCastNum + direction
  updateStage()
  repeat while the mouseDown
    if rollOver(loopBtnSpr) then
      set the castNum of sprite loopBtnSpr to theCastNum + direction
      set hilit to 1
    else
      set the castNum of sprite loopBtnSpr to theCastNum
      set hilit to 0
    end if
    updateStage()
  end repeat
  if hilit then
    set gLoopFlag to not gLoopFlag
  end if
end

on playBtnClick me
  set hilit to 1
  if gPlayFlag then
    set direction to -1
    set soundCastNum to the number of cast "stop snd"
    puppetSound(2, soundCastNum)
  else
    set direction to 1
    set soundCastNum to the number of cast "play snd"
    puppetSound(2, soundCastNum)
  end if
  set theCastNum to the castNum of sprite playBtnSpr
  set the castNum of sprite playBtnSpr to theCastNum + 1
  updateStage()
  if the mouseDown then
    repeat while the mouseDown
      if rollOver(playBtnSpr) then
        set the castNum of sprite playBtnSpr to theCastNum + 1
        set hilit to 1
      else
        set the castNum of sprite playBtnSpr to theCastNum
        set hilit to 0
      end if
      updateStage()
    end repeat
  end if
  unLoadCast(theCastNum + 1)
  unLoadCast(soundCastNum)
  if hilit then
    set the castNum of sprite playBtnSpr to theCastNum + (2 * direction)
    set gPlayFlag to not gPlayFlag
  else
    set the castNum of sprite playBtnSpr to theCastNum
  end if
  updateStage()
  if gPlayFlag then
    if the shiftDown then
      preview(playbackMgr)
    else
      playBackClip(playbackMgr, currentFrame)
    end if
  end if
end

on resetPanel me
  set the locH of sprite buttonHiliteSpr to -1000
  updateStage()
end

on forcePlayBtnClick me
  if not gPlayFlag then
    set soundCastNum to the number of cast "play snd"
    puppetSound(2, soundCastNum)
    set theCastNum to the castNum of sprite playBtnSpr
    set the castNum of sprite playBtnSpr to theCastNum + 1
    updateStage()
    startTimer()
    repeat while the timer < 6
    end repeat
    unLoadCast(theCastNum + 1)
    unLoadCast(soundCastNum)
    set the castNum of sprite playBtnSpr to theCastNum + 2
    set gPlayFlag to not gPlayFlag
    updateStage()
    if the shiftDown then
      preview(playbackMgr)
    else
      playBackClip(playbackMgr, currentFrame)
    end if
  end if
end

on forceBtnClick me, soundCastName, hiliteCastName, hiliteButtonLoc, buttonAction
  set soundCastNum to the number of cast soundCastName
  puppetSound(2, soundCastNum)
  set hiliteCastNum to the number of cast hiliteCastName
  set the castNum of sprite buttonHiliteSpr to hiliteCastNum
  set the loc of sprite buttonHiliteSpr to hiliteButtonLoc
  set the width of sprite buttonHiliteSpr to the width of cast hiliteCastNum
  set the height of sprite buttonHiliteSpr to the height of cast hiliteCastNum
  set hilite to 1
  updateStage()
  startTimer()
  repeat while the timer < 6
  end repeat
  set the locH of sprite buttonHiliteSpr to -1000
  updateStage()
  unLoadCast(soundCastNum)
  unLoadCast(hiliteCastNum)
  cursor(4)
  do(buttonAction)
  cursor(-1)
end